@echo off
setlocal EnableExtensions

set "CONFIG_PATH=/home/hyein/project/server/ptc_source_path.txt"
set "SELECTED_FILE="
set "WSL_SOURCE_PATH="

for /f "usebackq delims=" %%i in (`powershell -NoProfile -STA -Command "Add-Type -AssemblyName System.Windows.Forms; $dialog = New-Object System.Windows.Forms.OpenFileDialog; $dialog.Filter = 'Excel Files (*.xlsx)|*.xlsx'; $dialog.Title = 'PTC 원본 엑셀 파일 선택'; $dialog.InitialDirectory = [Environment]::GetFolderPath('Desktop'); if ($dialog.ShowDialog() -eq [System.Windows.Forms.DialogResult]::OK) { $dialog.FileName }"`) do (
    set "SELECTED_FILE=%%i"
)

if "%SELECTED_FILE%"=="" (
    echo 파일 선택이 취소되었습니다.
    pause
    exit /b 1
)

echo 선택한 파일:
echo %SELECTED_FILE%

for /f "usebackq delims=" %%i in (`wsl.exe wslpath -a "%SELECTED_FILE%"`) do (
    set "WSL_SOURCE_PATH=%%i"
)

if "%WSL_SOURCE_PATH%"=="" (
    echo WSL 경로 변환에 실패했습니다.
    pause
    exit /b 1
)

wsl.exe bash -lc "printf '%s\n' \"%WSL_SOURCE_PATH%\" > %CONFIG_PATH%"
if errorlevel 1 (
    echo 원본 파일 설정 저장에 실패했습니다.
    pause
    exit /b 1
)

echo 설정 저장 완료
echo 다음 실행부터 이 파일을 사용합니다.
echo.
echo 바로 서버를 다시 시작합니다...
call "%~dp0start_ptc_share.bat"